$!----------------------------------------------------------------------------+
$! HTTP_USER_REMAPS.COM - Add map rules for username changes                  |
$!----------------------------------------------------------------------------+
$!	P1 = Old username
$!	P2 = New username
$!	P3 = "SORT" if you wish the file sorted after the map rules are added
$!
$	SAVERIFY = 'F$VERIFY(0)'
$	ON ERROR THEN GOTO FINISHED
$	IF P1 .EQS. "" THEN INQUIRE P1 "Old username"
$	IF P1 .EQS. "" THEN GOTO FINISHED
$	IF P2 .EQS. "" THEN INQUIRE P2 "New username"
$	IF P2 .EQS. "" THEN GOTO FINISHED
$	OLDUSER = F$EDIT(P1,"LOWERCASE,TRIM")
$	NEWUSER = F$EDIT(P2,"LOWERCASE,TRIM")
$	CLOSE/NOLOG MAPFILE
$	MAPFILE = F$ELEMENT(0,";",F$ENVIRONMENT("PROCEDURE")) - ".COM" + ".CONF"
$	OPEN/APPEND/SHARE/ERROR=FINISHED MAPFILE 'MAPFILE'
$	WRITE MAPFILE "map /~''OLDUSER'   /htbin/userchanged/''OLDUSER'/''NEWUSER'/"
$	WRITE MAPFILE "map /~''OLDUSER'/* /htbin/userchanged/''OLDUSER'/''NEWUSER'/*"
$	CLOSE/NOLOG MAPFILE
$	WRITE SYS$OUTPUT "Map of ""''OLDUSER'"" to ""''NEWUSER'"" added."
$	IF P3 .EQS. "SORT"
$	THEN	SORT/NODUPL/STAT	'MAPFILE'	'MAPFILE'
$		PURGE/NOLOG/NOCONF	'MAPFILE'
$		RENAME/NOLOG/NOCONF	'MAPFILE'	'MAPFILE';1
$		WRITE SYS$OUTPUT ""
$	ENDIF
$	WRITE SYS$OUTPUT "The server must be restarted for the new map rules to take effect."
$ FINISHED:
$	CLOSE/NOLOG MAPFILE
$	EXIT 1 + 0*F$VERIFY(SAVERIFY)