$!----------------------------------------------------------------------------+
$!	CLOCK_Synch.COM - Keep cluster clocks synchronized                    |
$!----------------------------------------------------------------------------+
$!	Author: Harry Flowers
$!
$	SAVERIFY = 'F$VERIFY(0)'
$	SET NOON
$	IF (F$MODE() .NES. "OTHER") .OR. -		! Detached is OTHER
	   (F$GETJPI("","PRCNAM") .NES. "CLOCKsynch") - ! BUT SO IS STARTUP
	   THEN GOTO START_DETACHED			! so check proc name!
$ LOOP:
$	RUN SYS$SYSTEM:SYSMAN
SET ENVIRONMENT/CLUSTER
DO SHOW TIME
SET PROFILE/PRIV=(LOG_IO,SYSLCK,OPER)
CONFIG SET TIME
DO SHOW TIME
DO SET TIME
EXIT
$	WAIT 06:00:00
$	IF F$TRNLNM("SHUTDOWN$TIME") .EQS. "" THEN GOTO LOOP
$	EXIT 1 + 0*F$VERIFY(SAVERIFY)
$!
$ START_DETACHED:
$	WRITE SYS$OUTPUT "Starting CLOCKsynch process..."
$	RUN/DETACH/INPUT='F$ENVIRONMENT("PROCEDURE")'-
		/OUTPUT=SYS$MANAGER:CLOCK_SYNCH.LOG/PROCESS_NAME="CLOCKsynch" -
		SYS$SYSTEM:LOGINOUT.EXE
$	PURGE/NOLOG/NOCONFIRM/KEEP=4 SYS$MANAGER:CLOCK_SYNCH.LOG
$	EXIT 1 + 0*F$VERIFY(SAVERIFY)