$!----------------------------------------------------------------------------+
$!	AUTH - Run authorize, setting up logicals and showing file locations  |
$!----------------------------------------------------------------------------+
$	SAVERIFY = 'F$VERIFY(0)'		! Save and turn off verify
$	PREVPRIV = F$SETPRV("SYSPRV")		! Save and turn on SYSPRV
$!
$	AUTHFILE = F$PARSE("SYSUAF","SYS$SYSTEM:SYSUAF.DAT")	! Check SYSUAF
$	WRITE SYS$OUTPUT "[SYSUAF is ''AUTHFILE']"	! Show SYSUAF location
$	DEFINE/USER SYSUAF 'AUTHFILE'		! Set user mode SYSUAF logical
$!
$	RIGHTSFILE = F$PARSE("RIGHTSLIST","SYS$SYSTEM:RIGHTSLIST.DAT") ! Check
$	IF F$SEARCH(RIGHTSFILE) .NES. ""	! rightslist; if it exists,
$	THEN	WRITE SYS$OUTPUT "[RIGHTSLIST is ''RIGHTSFILE']" ! Show loc
$		DEFINE/USER RIGHTSLIST 'RIGHTSFILE'	! Set user mode log
$	ELSE	WRITE SYS$OUTPUT "[No RIGHTSLIST found]" ! Notify none exists
$	ENDIF
$!
$	NETFILE = F$PARSE("NETPROXY","SYS$SYSTEM:NETPROXY.DAT") ! Check proxy
$	IF F$SEARCH(NETFILE) .NES. ""			! If it exists,
$	THEN	WRITE SYS$OUTPUT "[NETPROXY is ''NETFILE']" ! Show location
$		DEFINE/USER NETPROXY 'NETFILE'		! Set user mode log
$	ELSE	WRITE SYS$OUTPUT "[No NETPROXY found]"	! Notify none exists
$	ENDIF
$!
$	DEFINE/USER SYS$INPUT SYS$COMMAND	! Redirect input to keyboard
$	RUN SYS$SYSTEM:AUTHORIZE		! Run AUTHORIZE
$!
$	PREVPRIV = F$SETPRV(PREVPRIV)		! Restore privileges
$	EXIT 1 + 0*F$VERIFY(SAVERIFY)		! Restore verification